昔の VB で要素数 0 の配列を使いたい

Dim stHoges() As String
stHoges = GetHogeArrays()  '配列を返す

If stHoges Is Nothing Then
    Exit Function
End If

  a = Split("", "/")
  Debug.Print "aの要素数 " & UBound(a) - LBound(a) + 1

'/* MyStrings モジュール */
Option Explicit

Private Declare Sub GetMem4 Lib "MSVBVM60.DLL" ( _
    ByRef aParam() As Any, _
    ByRef lCount   As Long _
)

'/ Is Nothing の代わり
Public Function IsNothing(ByRef stArgs() As String) As Boolean
    Dim lCount As Long

    Call GetMem4(stArgs, lCount)

    If lCount = 0 Then
        IsNothing = True
    Else
        IsNothing = False
    End If
End Function

'/ 未割り当ての状態を取得 (メソッド内は空でもいい)
Public Function GetNothing() As String()
    Dim stNullable() As String

    GetNothing = stNullable
End Function

'/ 配列 0 の状態を取得
Public Function GetEmpty() As String()
    GetEmpty = Split(vbNullString, vbNullChar)
End Function

'/* 実験用の Form */
Option Explicit

Private Sub Command1_Click()
    '/ 今回のターゲット
    Dim stHoges() As String

    '/ 未割り当てなので Null
    If MyStrings.IsNothing(stHoges()) = True Then
        Call MsgBox("Null")
    Else
        Call MsgBox("Not Null")
    End If

    '/ 要素を 1 つ割り当てる
    ReDim stHoges(0)

    '/ 割り当ててるので Not Null
    If MyStrings.IsNothing(stHoges()) = True Then
        Call MsgBox("Null")
    Else
        Call MsgBox("Not Null")
    End If

    '/ 未割り当てにする
    stHoges = MyStrings.GetNothing()

    '/ 未割り当てなので Null
    If MyStrings.IsNothing(stHoges()) = True Then
        Call MsgBox("Null!")
    Else
        Call MsgBox("Not Null!")
    End If

    '/ 実行時エラーになる
    'Call MsgBox(CStr(UBound(stHoges)))

    '/ 要素数 0 の配列にしてみる
    stHoges = MyStrings.GetEmpty()

    '/ 0 となる
    Call MsgBox(CStr(LBound(stHoges)))
    '/ -1 となる
    Call MsgBox(CStr(UBound(stHoges)))
End Sub

public class Hoge {
    
    public static int[] foo(int x) {
        if (x < 0) {
            return null;
        } else if (x == 0) {
            return new int[0];
        } else if (x > 0) {
            return new int[x];
        } else {
            throw new IllegalStateException();
        }
    }

    public static void bar(int[] x) {
        for (int i = 0; i < x.length; i++) {
            System.out.println("i = " + i + ", value = " + x[i]);
        }
    }
    
    public static void main(String[] args) {
        int[] a = Hoge.foo(-1); // null
        if (a != null) {
            bar(a);
        }
        
        int[] b = Hoge.foo(0); // int[0]
        if (b != null) {
            bar(b);
        }

        int[] c = Hoge.foo(1); // int[1]
        if (c != null) {
            bar(c);
        }
    }
}