クリップボードオブジェクトについて

    Private Sub Button1_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim oDataTable   As System.Data.DataTable
        Dim stStrings    As String(,)

        Try
            oDataTable = GetDataTable()
            stStrings = GetDataArray(oDataTable)
        Finally
            If Not oDataTable Is Nothing Then
                oDataTable.Dispose()
            End If
        End Try

        Dim xlApplication As Excel.Application

        Try
            xlApplication = New Excel.Application()
            'xlApplication.Visible = True
            Dim xlWorkbooks As Excel.Workbooks

            Try
                xlWorkbooks = xlApplication.Workbooks
                Dim xlWorkbook As Excel.Workbook

                Try
                    xlWorkbook = xlWorkbooks.Add()
                    Dim xlWorksheets As Excel.Sheets

                    Try
                        xlWorksheets = xlWorkbook.Worksheets
                        Dim xlWorksheet As Excel.Worksheet

                        Try
                            xlWorksheet = DirectCast(xlWorksheets(1), Excel.Worksheet)
                            Dim xlCells As Excel.Range

                            Try
                                xlCells = xlWorksheet.Cells
                                Dim xlRange As Excel.Range

                                Try
                                    xlRange = xlCells.Range("A1:Z3000")
                                    xlRange.Value2 = stStrings
                                Finally
                                    If Not xlRange Is Nothing Then
                                        System.Runtime.InteropServices.Marshal.ReleaseComObject(xlRange)
                                    End If
                                End Try
                            Finally
                                If Not xlCells Is Nothing Then
                                    System.Runtime.InteropServices.Marshal.ReleaseComObject(xlCells)
                                End If
                            End Try
                        Finally
                            If Not xlWorksheet Is Nothing Then
                                System.Runtime.InteropServices.Marshal.ReleaseComObject(xlWorksheet)
                            End If
                        End Try
                    Finally
                        If Not xlWorksheets Is Nothing Then
                            System.Runtime.InteropServices.Marshal.ReleaseComObject(xlWorksheets)
                        End If
                    End Try

                    xlApplication.DisplayAlerts = False
                    xlWorkbook.SaveAs("C:\MosaMosaAA.xls")
                Finally
                    If Not xlWorkbook Is Nothing Then
                        Try
                            xlWorkbook.Close()
                        Finally
                            System.Runtime.InteropServices.Marshal.ReleaseComObject(xlWorkbook)
                        End Try
                    End If
                End Try
            Finally
                If Not xlWorkbooks Is Nothing Then
                    System.Runtime.InteropServices.Marshal.ReleaseComObject(xlWorkbooks)
                End If
            End Try
        Finally
            If Not xlApplication Is Nothing Then
                Try
                    xlApplication.Quit()
                Finally
                    System.Runtime.InteropServices.Marshal.ReleaseComObject(xlApplication)
                End Try
            End If
        End Try
    End Sub

    Private Shared Function GetDataArray(ByVal oDataTable As System.Data.DataTable) As String(,)
        Dim iRowCount     As Integer   = oDataTable.Rows.Count
        Dim iColumnsCount As Integer   = oDataTable.Columns.Count
        Dim stReturns     As String(,) = New String(iRowCount - 1, iColumnsCount - 1) {}

        For iRow As Integer = 0 To oDataTable.Rows.Count - 1
            Dim oDataRow As System.Data.DataRow = oDataTable.Rows(iRow)

            For iColumn As Integer = 0 To iColumnsCount - 1
                stReturns(iRow, iColumn) = oDataRow(iColumn).ToString()
            Next
        Next

        Return stReturns
    End Function

    Private Shared Function GetDataTable() As System.Data.DataTable
        Dim oConnection As System.Data.SqlClient.SqlConnection

        Try
            oConnection = New System.Data.SqlClient.SqlConnection(...)
            Dim oDataAdapter As System.Data.SqlClient.SqlDataAdapter

            Try                
                oDataAdapter = New System.Data.SqlClient.SqlDataAdapter("SELECT * FROM Orders", oConnection)
                Dim oDataTable As New System.Data.DataTable("Orders")
                oDataAdapter.Fill(oDataTable)

                Return oDataTable
            Finally
                If Not oDataAdapter Is Nothing Then
                    oDataAdapter.Dispose()
                End If
            End Try
        Finally
            If Not oConnection Is Nothing Then
                oConnection.Dispose()
            End If
        End Try 
    End Function