VBSであるフォルダの以下特定のファイルを全て参照する方法

Option Explicit

Private objFSO

Call Main()
WScript.Quit

Public Sub Main()
    Dim strPath
    Dim strExt
    Dim blnSubFolder

    strPath = "C:\DelFile"  ' 削除対象ディレクトリ
    strExt = "txt"          ' 削除対象拡張子
    blnSubFolder = True     ' サブディレクトリ対象フラグ
    
    Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
    
    Call DeleteTextFile(objFSO.GetFolder(strPath), strExt, blnSubFolder)
    WScript.Echo "終了"
    
    Set objFSO = Nothing
End Sub

Private Sub DeleteTextFile(ByVal objFolder, ByVal strExt, ByVal blSubFolder)
    Dim objFile
    Dim objSubFolder
    
    ' サブディレクトリのファイルも削除するか
    If blSubFolder Then
        For Each objSubFolder In objFolder.SubFolders
            Call DeleteTextFile(objSubFolder, strExt, True)
        Next
    End If
    ' 対象ファイルの削除
    For Each objFile In objFolder.Files
        ' 拡張子の確認(小文字に変換して比較)
        If LCase(objFSO.GetExtensionName(objFile.Name)) = strExt Then
            Call objFile.Delete()
        End If
    Next
End Sub

    Option Explicit

    Call Main()

    Private Sub Main()
        Call DeleteFileMostDeep("C:\ぽぴ王子\House", "txt")    
    End Sub

    Private Sub DeleteFileMostDeep(stDirectoryPath, stExtension)
        stExtension = LCase(stExtension)

        Dim oFso 'As Scripting.FileSystemObject
        Set oFso = CreateObject("Scripting.FileSystemObject")

        Dim oFirstFolder 'As Scripting.Folder
        Set oFirstFolder = oFso.GetFolder(stDirectoryPath)

        Dim oFolder 'As Scripting.Folder
        For Each oFolder In oFirstFolder.SubFolders
            Call DeleteFileMostDeep(oFolder.Path, stExtension)
        Next

        Set oFolder = Nothing

        Dim oFile 'As Scripting.File
        For Each oFile In oFirstFolder.Files
            If LCase(oFso.GetExtensionName(oFile.Name)) = stExtension Then
                Call oFile.Delete(True)
            End If
        Next

        Set oFile = Nothing
        Set oFirstFolder = Nothing
        Set oFso = Nothing
    End Sub