[vb.net]TextBox + Combobox で DataGridViewComboBoxColumn.DataPropertyName と同様な機能を実装したい

※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※

※　このコードの提示当初、バグがありました。

※　ペアのコントロールが、GroupBox や Panel 等のコンテナ上に配置されている場合、

※　正しく機能しませんでした。

※　以下のものは修正版です。

※　（さらに修正が加わっています。）

※　　万　が　一　コピーして持っていってくださった方がいらっしゃいましたら、

※　修正していただいた上、もう一度十分なテストを行っていただくようお願いします。

※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※※

''' -----------------------------------------------------------------------------

''' <summary>

'''     SelectedValue の値を自動でペアになるコントロールの

''' 　　 Text プロパティと同期を取る ComboBox クラス </summary>

''' -----------------------------------------------------------------------------

Public Class LinkageComboBox

    Inherits System.Windows.Forms.ComboBox



    ' コンストラクタ

    Public Sub New()

        MyBase.New()

        Me.DataPropertyName = String.Empty

    End Sub



    ' ペアのコントロールの名前

    Private _DataPropertyName As String



    ' _DataPropertyName の窓口

    <System.ComponentModel.Category("動作"), _

     System.ComponentModel.Description("アイテムのコードを入力する Textプロパティを持つ" _

                                     & "コントロールの名前を設定します。")> _

    Public Property DataPropertyName() As String

        Get

            Return Me._DataPropertyName

        End Get



        Set(ByVal value As String)

            Me._DataPropertyName = value

        End Set

    End Property



    ' 未選択状態の値

    Dim notSelected As Integer = -1



    ' フォーカスを受取ったとき、ペアのコントロールの Text を ValueMember にセットする

    Protected Overrides Sub OnEnter(ByVal e As EventArgs)

        Try

            Dim pair As Control = GetPair()

            If IsNothing(pair) Then Exit Sub

            Me.SelectedIndex = notSelected

            If String.IsNullOrEmpty(pair.Text) Then Exit Sub



            Dim tbl As Data.DataTable = DirectCast(Me.DataSource, Data.DataTable)

            Dim row As Data.DataRow

            For Each row In tbl.Rows

                If row.Item(Me.ValueMember).ToString = pair.Text.ToString Then

                    Me.SelectedValue = pair.Text

                    Exit Sub

                End If

            Next

        Finally

            MyBase.OnEnter(e)

        End Try

    End Sub



    ' フォーカスが離れるとき、ペアのコントロールに ValueMember をセットする

    Protected Overrides Sub OnValidated(ByVal e As System.EventArgs)

        Try

            If Me.SelectedIndex = notSelected Then Exit Sub

            Dim pair As Control = GetPair()

            If IsNothing(pair) Then Exit Sub

            pair.Text = Me.SelectedValue.ToString

        Finally

            MyBase.OnValidated(e)

        End Try

    End Sub



    ' ペアのコントロールを探すプロシージャ

    Private Function GetPair() As Control

        If _DataPropertyName = String.Empty Then Return Nothing

        Dim parent As Control = Me.Parent

        Dim pair As Control = parent.Controls(_DataPropertyName)

        Do While (IsNothing(pair))

            If Object.Equals(parent, Me.FindForm) Then Return Nothing

            parent = parent.Parent

            pair = parent.Controls(_DataPropertyName)

        Loop

        Return pair

    End Function

End Class