ADO レコード参照

Private Sub OneMethod()
    ' 接続文字列を生成する
    Dim nConnectionString As String
    nConnectionString = nConnectionString & "Driver={SQL Server};"
    nConnectionString = nConnectionString & "Server=Server;"
    nConnectionString = nConnectionString & "Database=Northwind;"

    ' ADODB.Connection の新しいインスタンスを生成する
    Dim oConnection As ADODB.Connection
    Set oConnection = New ADODB.Connection

    ' ADODB.Connection の接続を確立する
    Call oConnection.Open(nConnectionString)

    ' 実行時エラー発生時でも Connection の Close を保証する
    On Error GoTo Finally1

    ' ADODB.Recordset の新しいインスタンスを生成する
    Dim oRecordset As ADODB.Recordset
    Set oRecordset = New ADODB.Recordset

    ' SQL コマンド テキストの生成
    Dim nSqlCommand As String
    nSqlCommand = "SELECT COUNT(DISTINCT EmployeeID) FROM Employees"

    ' 指定されたコマンド テキストで Recordset を開く
    Call oRecordset.Open(nSqlCommand, oConnection, adOpenForwardOnly, adLockReadOnly, adCmdText)

    ' 実行時エラー発生時でも Recordset と Connection の Close を保証する
    On Error GoTo Finally2

    ' ここはテスト専用
    If oRecordset.EOF = False Then
        Call MsgBox(oRecordset.Fields(0).Value)
    End If

Finally2:
    ' Recordset を Close する
    If Not oRecordset Is Nothing Then
        If oRecordset.State <> ObjectStateEnum.adStateClosed Then
            oRecordset.Close
        End If

        Set oRecordset = Nothing
    End If

Finally1:
    ' Connection を Close する
    If Not oConnection Is Nothing Then
        If oConnection.State <> ObjectStateEnum.adStateClosed Then
            oConnection.Close
        End If

        Set oConnection = Nothing
    End If
End Sub

SQL1 = "select count(distinct page_id) from documentation"