SQLServerで複数行を１行にしたい。

TestDataテーブル

(両列ともvarchar(10)で定義)



col1 | col2

-------------

1    | 100

1    | 200

1    | 300

1    | 400

1    | 500

1    | 600

2    | 1000

2    | 2000

3    | 3000

3    | 10000

3    | 20000

select

	col1,

	COALESCE([1],0) '1行目' ,

	COALESCE([2],0) '2行目',

	COALESCE([3],0) '3行目',

	COALESCE([4],0) '4行目',

	COALESCE([5],0) '5行目'

from

	(

	select

		row_number() over(partition by col1 order by col2) num,

		col1,

		col2

	from TestTable

	) P

	Pivot

	(

		min(col2) for num In ([1],[2],[3],[4],[5])

	) Base

;

col1 | 1行目 | 2行目 | 3行目 | 4行目 | 5行目 

----------------------------------------------

1    | 100   | 200   | 300   | 400   | 500

2    | 1000  | 2000  | 0     | 0     | 0

3    | 3000  | 10000 | 20000 | 0     | 0

/* カーソル */
Declare @cur CURSOR ;
set @cur = CURSOR FOR
Select
	col1, col2
From Test1 base 
Where
  base.col2 in ( 
    select top 5 col2 from Test1 p where p.col1 = base.col1 ) 
;

/* 戻りデータ格納テーブル変数 */
Declare @tmp Table (
	col1 char(3),
	col21 char(3),
	col22 char(3),
	col23 char(3),
	col24 char(3),
	col25 char(3)
) ;


/* 前レコードの項目1 */
Declare @prev char(3) ;
/* インクリメント用変数 */
Declare @inc int ;

Set @prev = '' ;
Set @inc = 1 ;

/* 取得データ格納変数 */
Declare @col1 char(3) ;
Declare @col2 char(3) ;


/* 追加データ格納変数 */
Declare @tcol1 char(3) ;
Declare @tcol21 char(3) ;
Declare @tcol22 char(3) ;
Declare @tcol23 char(3) ;
Declare @tcol24 char(3) ;
Declare @tcol25 char(3) ;

set @tcol21 = '0' ;
set @tcol22 = '0' ;
set @tcol23 = '0' ;
set @tcol24 = '0' ;
set @tcol25 = '0' ;

/* カーソルオープン */
Open @cur ;

/* データがなくなるまでループ */
Fetch Next From @cur into @col1,@col2 ;
While @@FETCH_STATUS = 0
Begin

	/* 前回の項目1と今回の項目1が異なる場合 */
	If @prev <> @col1
	begin
		/* 前回項目が入っている場合(初回でない場合) */
		if len(@prev) > 0
		begin
			/* 戻り変数テーブルへデータを追加し、変数を再初期化 */
			insert into @tmp values(@tcol1,@tcol21,@tcol22,@tcol23,@tcol24,@tcol25 ) ;
			set @tcol21 = '0' ;
			set @tcol22 = '0' ;
			set @tcol23 = '0' ;
			set @tcol24 = '0' ;
			set @tcol25 = '0' ;
		end ;
		
		/* 変数初期化 */
		set @prev = @col1 ;
		set @tcol1 = @col1 ;
		Set @inc = 2 ;
		Set @tcol21 = @col2 ;
	End ;
	Else
	Begin
		
		/* インクリメントの数値により、設定する列を変える */
		if @inc = 2 
			Set @tcol22 = @col2 ;
		if @inc = 3 
			Set @tcol23 = @col2 ;
		if @inc = 4 
			Set @tcol24 = @col2 ;
		if @inc = 5 
			Set @tcol25 = @col2 ;
		
		set @inc = @inc+1 ;
	End ;
	Fetch Next From @cur into @col1,@col2 ;
End;

/* ループを抜けたときにデータが存在していたらインサートする */
if len(@prev) > 0
begin
	insert into @tmp values(@tcol1,@tcol21,@tcol22,@tcol23,@tcol24,@tcol25 ) ;
end ;

select * from @tmp ;

Close @cur ;