第17回　FileSystemObjectオブジェクトを利用する（2）：基礎解説 演習方式で身につけるチェック式WSH超入門（4/5 ページ）

マーカーで隠れたところを選択してチェックしてみよう。

※ファイル：RenameFile.vbs

Option Explicit

Dim objFSO
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

Dim strArgument
Dim objFile
Dim strNewFileName

If WScript.Arguments.Count > 0 Then 'コマンドライン引数が存在すれば
    strArgument = WScript.Arguments(0) '一つ目の引数を取る
    'もし引数がファイルなら
    If objFSO.FileExists(strArgument)Then
        On Error Resume Next
        'Fileオブジェクト取得
        Set objFile = objFSO.GetFile(strArgument)
        strNewFileName = InputBox( _
            "新しいファイル名を入力してください。" & vbCrLf & _
            "現在のファイル名は " & vbCrLf & _
            objFile.Name & vbCrLf & _
            "です。", , objFile.Name
        If strNewFileName <> "" Then
            If strNewFileName <> objFile.Name Then
                'もし現在の名前と違う名前が指定されたら、指定された名前に変える
                objFile.Name = strNewFileName
            Else
                MsgBox "ファイル名が同じです。" ,vbCritical
            End If
           
            Select Case Err.Number
            Case 0 'エラーがなければ何もしない
            Case 70
                MsgBox "書き込みできませんでした。" ,vbCritical
            Case 58
                MsgBox "すでに同名のファイルが存在しています。" ,vbCritical
            Case 52
                MsgBox "次の文字はファイル名に使用できません。" & vbCrLf & _
                       "\ / : , ; * ? "" < > |", vbCritical
            Case Else
                MsgBox Err.Number & ": " & Err.Description, vbCritical
            End Select
        End If
        On Error Goto 0
    Else
        MsgBox "ファイルのパスを指定してください。", vbExclamation
    End If
End If

Set objFile = Nothing
Set objFSO = Nothing

objFile.Attributes = ReadOnly + Archive '読み取り専用とアーカイブ属性にする

If (objFile.Attributes And ReadOnly) = ReadOnly Then
    objFile.Attributes = objFile.Attributes - ReadOnly '読み取り専用属性を外す
End If

objFile.Attributes = objFile.Attributes And Not ReadOnly '読み取り専用属性を外す

objFile.Attributes = (objFile.Attributes Or ReadOnly) '読み取り専用属性を付ける