第18回　FileSystemObjectオブジェクトを利用する（3）：基礎解説 演習方式で身につけるチェック式WSH超入門（2/2 ページ）

※ファイル：showDriveInfo.vbs

Option Explicit

Dim objFSO
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

'Driveオブジェクトとドライブ名を格納する変数宣言
Dim objDrive, strDrive
strDrive = "C:" 'ドライブ名（適宜変更のこと）

'ドライブが存在するかどうかチェックし、存在する場合のみ処理を行う
If objFSO.DriveExists(strDrive) Then
       'Driveオブジェクトの取得と変数への格納
       Set objDrive = objFSO.GetDrive(strDrive)

       'Driveオブジェクトのプロパティを格納する変数宣言
       Dim strDriveTypeName, strSerialNumber, strSerialHexNumber ,strFileSystem, strVolumeName, strUsedSize, strAvailableSize, strTotalSize, strIsReadyMessage

       'DriveTypeプロパティを参照し、ドライブの種類を文字列化する
       Select Case objDrive.DriveType
              Case 0 strDriveTypeName = "不明"
              Case 1 strDriveTypeName = "リムーバブルドライブ"
              Case 2 strDriveTypeName = "ハードディスク"
              Case 3 strDriveTypeName = "ネットワークドライブ"
              Case 4 strDriveTypeName = "CD-ROM"
              Case 5 strDriveTypeName = "RAMドライブ"
       End Select
      
       'IsReadyプロパティがTrueかFalseかで条件分岐する
       If objDrive.IsReady Then
              strIsReadyMessage  = "(このドライブは準備ができています)"
              strSerialNumber    = objDrive.SerialNumber
              strSerialHexNumber = Hex(CLng(strSerialNumber))
              strFileSystem      = objDrive.FileSystem
              strVolumeName      = objDrive.VolumeName
              strAvailableSize   = ModifySize(objDrive.FreeSpace)
              strTotalSize       = ModifySize(objDrive.TotalSize)
              strUsedSize        = ModifySize(objDrive.TotalSize - objDrive.FreeSpace)
       Else
              strIsReadyMessage  = "(このドライブは準備ができていません)"
              strSerialNumber    = ""
              strSerialHexNumber = ""
              strFileSystem      = ""
              strVolumeName      = ""
              strAvailableSize   = ""
              strTotalSize       = ""
              strUsedSize        = ""
       End If
      
       MsgBox "ドライブ "           & objDrive.DriveLetter & vbCrLf & vbCrLf & _
              "ボリュームラベル : " & strVolumeName & vbCrLf & _
              "種類 : "             & strDriveTypeName & vbCrLf & _
              "ファイルシステム : " & strFileSystem & vbCrLf & _
              "シリアルNO : "       & strSerialNumber & " (" & strSerialHexNumber & ")" & vbCrLf & _
              "パス : "             & objDrive.Path & vbCrLf & _
              "共有名 : "           & objDrive.ShareName & vbCrLf & _
              "使用領域 : "         & strUsedSize & vbCrLf & _
              "空き領域 : "         & strAvailableSize & vbCrLf &  _
              "容量 : "             & strTotalSize  & vbCrLf & _
               strIsReadyMessage
End If

Function ModifySize(numSize)
       If numSize >= 1073741824 Then
              ModifySize = FormatNumber(numSize / 1073741824, 2) & "GB"
       ElseIf numSize >= 1048576 Then
              ModifySize = FormatNumber(numSize / 1048576, 2) & "MB"
       ElseIf numSize >= 1024 Then
              ModifySize = FormatNumber(numSize / 1024, 2) & "KB"
       Else
              ModifySize = FormatNumber(numSize, 0) & "バイト"
       End If
End Function

マーカーで隠れたところを選択してチェックしてみよう。

※ファイル：showDrivesInfo.vbs

Option Explicit

Dim objFSO
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

'Drivesコレクションを取得
Dim objDrives, objDrive
Set objDrives = objFSO.Drives

Dim strMessage
strMessage = ""

'各Driveオブジェクトのプロパティを格納する変数宣言
Dim numFreeSpace, numTotalSize, numUsedSize, numRatio, strDriveLetter

'Drivesコレクションに含まれる各Driveオブジェクトを列挙
For Each objDrive In objDrives
       'ドライブの種類がハードディスクなら
       If objDrive.DriveType = 2 Then
              'ドライブの準備ができていれば
              If objDrive.IsReady Then
                     'ドライブレターを取得する
                     strDriveLetter = objDrive.DriveLetter
                     '空き容量を取得する
                     numFreeSpace = objDrive.FreeSpace
                     '総容量を取得する
                     numTotalSize = objDrive.TotalSize
                     '使用量を計算する
                     numUsedSize = numTotalSize - numFreeSpace
                     'ディスク使用率を計算する(パーセンテージ)
                     numRatio = numUsedSize / numTotalSize * 100
              'ドライブが準備できていなければすべて0にする
              Else
                     numFreeSpace = 0
                     numTotalSize = 0
                     numUsedSize = 0
                     numRatio = 0
              End If
             
              '各プロパティ情報を文字列変数に追記
              strMessage = strMessage & _
                           strDriveLetter & vbTab & _
                           ModifySize(numTotalSize) & vbTab & _
                           ModifySize(numFreeSpace) & vbTab & _
                           ModifySize(numUsedSize) & vbTab & _
                           FormatNumber(numRatio, 0) & " %" & vbCrLf
       End If
Next

MsgBox "システムに接続されている全HDDの情報" & vbCrLf & _
       "ドライブ" & vbTab & _
       "総容量" & vbTab & _
       "空き容量" & vbTab & _
       "使用量" & vbTab & _
       "使用率" & vbTab & _
       vbCrLf & strMessage

Function ModifySize(numSize)
       If numSize >= 1073741824 Then
              ModifySize = FormatNumber(numSize / 1073741824, 0) & "GB"
       ElseIf numSize >= 1048576 Then
              ModifySize = FormatNumber(numSize / 1048576, 0) & "MB"
       ElseIf numSize >= 1024 Then
              ModifySize = FormatNumber(numSize / 1024, 0) & "KB"
       Else
              ModifySize = FormatNumber(numSize, 0) & "バイト"
       End If
End Function