第14回　WshShellオブジェクトを利用する（3）：基礎解説 演習方式で身につけるチェック式WSH超入門（1/4 ページ）

Option Explicit

Dim objWshShell
Set objWshShell = WScript.CreateObject("WScript.Shell")

'WshScriptExecオブジェクトを格納する変数を宣言
Dim objExec
'メモ帳を実行すると同時にWshScriptExecオブジェクトを変数に格納
Set objExec = objWshShell.Exec("notepad.exe")

'Statusプロパティが0の間、空ループを回す
Do While objExec.Status = 0
    WScript.Sleep 100
Loop

'Statusプロパティが1になったらループを抜け終了処理
MsgBox "メモ帳を終了しました"

Set objExec = Nothing
Set objWshShell = Nothing

Option Explicit

Dim objWshShell
Set objWshShell = WScript.CreateObject("WScript.Shell")

'WshScriptExecオブジェクトを格納する変数を宣言
Dim objExec
'メモ帳を実行すると同時にWshScriptExecオブジェクトを変数に格納
Set objExec = objWshShell.Exec("notepad.exe")

'もしメモ帳が起動中なら
If objExec.Status = 0 Then
    'メモ帳をアクティブ化し、文字コードを送る
    ActivateAndSendKeys objExec.ProcessId, "Happy! Lucky! Scripting!!",1000
End If

'5秒待つ。
WScript.Sleep 5000

'もしメモ帳が起動中なら
If objExec.Status = 0 Then
    'メモ帳を終了する
    objExec.Terminate
End If

Set objExec = Nothing
Set objWshShell = Nothing

'*********************************************************
'用途: 指定したプロセスIDのウィンドウをアクティブにし、指定
'      したキー・コードを送り、数ミリ秒待つ
'受け取る値:    lngID: プロセスID（Long）
'              strKey: 送るキー・コード（String）
'             intWait: キー・コードを送った後待つミリ秒数
'                      （Integer）
'戻り値: 成功したらTrue、失敗したらFalseを返す（Boolean）
'*********************************************************
Function ActivateAndSendKeys(lngID, strKey, intWait)
    Dim intCounter
    '10回試行する
    For intCounter = 1 To 10
        'AppActivateメソッドを実行し、戻り値がTrueなら、
        If objWshShell.AppActivate(lngID) Then
            WScript.Sleep 100
            'キー・コードを送る
            objWshShell.SendKeys strKey
            'intWaitミリ秒待つ。
            WScript.Sleep intWait
            '成功を意味するTrueを返し、ループを抜ける
            ActivateAndSendKeys = True
            Exit For
        Else
            WScript.Sleep 1000
            '失敗を意味するFalseを返し、続行
            ActivateAndSendKeys = False
        End If
    Next
End Function

Option Explicit

Dim objWshShell
Set objWshShell = WScript.CreateObject("WScript.Shell")

Dim objExec
Set objExec = objWshShell.Exec("ipconfig.exe") 'ipconfig.exeを起動
MsgBox objExec.StdOut.ReadAll '標準出力をすべて読み込み、表示

Set objExec = Nothing
Set objWshShell = Nothing

マーカーで隠れたところを選択してチェックしてみよう。

Option Explicit

Dim objWshShell
Set objWshShell = WScript.CreateObject("WScript.Shell")

Dim objExec, objStdOut, strLine, strIPAddress
strIPAddress = ""
Set objExec = objWshShell.Exec("ipconfig.exe") 'ipconfig.exeを起動
Set objStdOut = objExec.StdOut '標準出力を取得。
Do Until objStdOut.AtEndOfStream 'TextStreamの最後までループ
    strLine = objStdOut.ReadLine '1行読む
    If InStr(strLine,"IP Address") Then 'IP Addressが含まれる行なら（XP）
        '44文字目から後はIPアドレスなので取得
        strIPAddress = strIPAddress & Trim(Mid(strLine,44)) & vbCrLf
    ElseIf InStr(strLine,"IPv4 アドレス") Then 'IPv4 アドレスなら（Vista）
        '35文字目から後はIPアドレスなので取得
        strIPAddress = strIPAddress & Trim(Mid(strLine,35)) & vbCrLf
    End If
Loop
objStdOut.Close 'TextStreamを閉じる

MsgBox strIPAddress 'IPアドレスを表示

Set objStdOut = Nothing
Set objExec = Nothing
Set objWshShell = Nothing