いまさら聞けないAdobe AIR「超」入門：作って学ぶAIRウィジェットの基礎→応用（1）（4/4 ページ）

» 2008年01月25日 00時00分公開

[福田寅成，クラスメソッド株式会社]

アプリケーションのイベントを実装してみよう

　ここまでで、プログラムの骨格はすべてできました。後は、イベントハンドラの中身を実装するだけです。下記にイベントハンドラごとの処理の実装例を挙げます。

手順【1】初期起動イベントハンドラの実装

ソースコード7　初期起動イベントハンドラの実装

     private function onCreationComplete():void {

                      // タイマーオブジェクトの初期化

                      timer = new Timer(TIMER_INTERVAL);

                      // イベントハンドラの設定

        // （イベントの種類とイベントハンドラ関数名）

        timer.addEventListener(TimerEvent.TIMER, onTimerTick);

                      // 時刻の初期表示を03:00にする

                      timeLabel.text = "03:00";

                }

　ここでのポイントはタイマーオブジェクトへのイベントハンドラ（リスナ）の登録です。addEventListernerの第1引数はイベントの種類（ここでは一定時間ごとにイベントが発生するタイプのイベント）、第2引数はイベントハンドラの関数名です。この「onTimerTick」関数は後で実装します。

手順【2】スタートボタンをクリック時のイベントハンドラの実装

ソースコード8　スタートボタンクリックイベントハンドラの実装

     private function onStartButtonClick():void {

                      // 開始時刻を取得

                      startTime = getTimer();

                      // タイマーをスタート

                      timer.start();

                }

　getTimer()関数で現在時刻を取得し、タイマーをスタートさせています。タイマースタート後TIMER_INTERVALミリ秒ごとにonTimerTick関数が呼ばれることになります。このgetTimer()関数は「import文」を使ってMXMLに読み込まないと使えません。

　import文を書くのは面倒なので、「gett」と入力してCtrl＋Spaceキーで入力候補を表示し、Enterキーを押せば、ソースコードの一番上の方に以下のimport文が追加されます。

ソースコード9　自動的なimport文の追加

import flash.utils.getTimer

手順【3】ストップ・ボタンをクリック時のイベントハンドラの実装

ソースコード10　ストップボタンクリックイベントハンドラの実装

     private function onStopButtonClick():void {

                      // タイマーを停止

                      timer.stop();

                }

　タイマーを停止しているだけのシンプルな実装です。

手順【4】リセット・ボタンをクリック時のイベントハンドラの実装

ソースコード11　リセットボタンクリックイベントハンドラの実装

     private function onResetButtonClick():void {

                      // タイマーを停止

                      timer.stop();

                      // ラベルの表示をデフォルトに戻す

                      timeLabel.text = "03:00";

                }

　タイマーを停止して、時刻の表示を初期値の「03:00」に戻しています。

　ここまで実装しましたが、「onTimerTick」関数が存在していないので、実行しようとしてもエラーで中断してしまいます。

手順【5】タイマーのイベントハンドラの実装

　タイマーイベントのイベントハンドラであるonTimerTick関数を関数の定義から実装していきます。

ソースコード12　タイマーイベントハンドラの実装

     private function onTimerTick(event:TimerEvent):void {

                      // 経過時間（秒）

                      var elapsedTime:int = (getTimer() - startTime)/1000;

                      // 3分から経過時間を引く

                      var dispTime:int = 60*3 - elapsedTime;

                      // 表示時刻をフォーマットし、ラベルに表示する

                      if(dispTime >= 60) {

                          var min:int = dispTime/60;

                          var sec:int = dispTime - 60*min;

                          timeLabel.text = formatTime(min, sec);

                      } else if(dispTime >= 0) {

                          timeLabel.text = formatTime(0, dispTime);

                      } else {

                          timeLabel.text = "00:00";

                          timer.stop(); 

                      }

                }

　シンプルに表示時刻を計算しています。ここで「formatTime」という関数が出てきていますが、これは下記のようなユーティリティ関数です。onTimerTick関数の直下に実装しておきましょう。

ソースコード13　時刻フォーマットするユーティリティ関数の実装

     private function formatTime(min:int, sec:int):String {

                      var minString:String = "";

                      var secString:String = "";

              

                      if(min < 10) {

                          minString = "0" + String(min);

                      } else {

                          minString = String(min);

                      }

              

                      if(sec < 10) {

                          secString = "0" + String(sec);

                      } else {

                          secString = String(sec);

                      }

                      return minString.concat(":").concat(secString);

                }