第4回 関数を使いこなす（その1） 文字列、数値、日付を扱う関数：基礎解説 演習方式で身につけるチェック式WSH超入門（4/4 ページ）
日付処理関数 その1（日時を取得する）
これまで大きく分けて文字列と数値を扱う関数を見てきたが、今回の最後に日付と時間を扱う関数を取り上げる。
まず、現在の日時を取得するNow、Date、Time関数を見ていこう。
Option Explicit
MsgBox "今の日付と時刻：" & Now & vbCrLf & _
"今日の日付：" & Date & vbCrLf & _
"今の時刻：" & Time
このスクリプトを実行すると、次のメッセージ・ボックスが表示される。
Now、Date、Time関数の実行例このように、Now関数は現在の日付（年月日）と時刻（時分秒）を、Date関数とTime関数はそれぞれ日付と時刻を返す。これらの関数は日付型の値を返すが、MsgBox関数の引数としているので文字列型に変換されて表示される。
実際にコードを書く際には、現在の日時すべてではなく、いま何時か、あるいは、今日は何月か、といった、日時の一部の値が必要となることが多い。そのために用意されているのが、日付から年、月、日を得るYear関数、Month関数、Day関数と、時刻から時間、分、秒を得るHour関数、Minute関数、Second関数である。例を挙げよう。
Option Explicit
Dim dtmNow
dtmNow = Now
MsgBox "今日は" & Month(dtmNow) & "月" & Day(dtmNow) & "日です。"
スクリプトの実行結果は次のとおり。
Month関数、Day関数の実行例この例では、Now関数の戻り値をdtmNow変数（接頭辞dtmはDateTimeの略）に代入し、その値から月と日の値を抜き出して表示している。なお、時間や分、秒を取得したいなら、同様にHour、Minute、Secondの各関数を使えば可能となるので、各自確認してもらいたい。
日付処理関数 その2（曜日を取得する）
日付を扱うときに必要となることが多いのが、曜日に関する情報だ。VBScriptには引数に指定した曜日を数値として取得するWeekday関数と、曜日を示す数値から曜日名（「月曜日」など）を取得するWeekdayName関数が用意されている。
Option Explicit
Dim dtmNewYearsDay
dtmNewYearsDay = #2007/1/1# '来年の正月を示す日付リテラル
MsgBox dtmNewYearsDay & "は" & WeekdayName(Weekday(dtmNewYearsDay)) '曜日を返す
実行結果は次のとおり。
Weekday関数、WeekdayName関数の実行例ここで関数の説明に入る前に、日付リテラルの説明をしよう。これまでに文字列リテラル、数値リテラルを利用してきたが、日付型にも同様に特定の日付や時刻を示す日付リテラル、時刻リテラルが存在する。日付、時刻リテラルは##（シャープ）でくくるのがルールだ。なお、例のほかに#Jan 1 2007#などの表記も受け付ける。#2007/01/01 12:00#のように時刻を併記することも可能である。余談だが、年月日を数値でそれぞれ指定すると日付型の値を返すDateSerial関数を使って、DateSerial(2007, 1, 1)のようにしてもよい。
これらの値をMsgBox関数などで表示するときは、コントロールパネルの「地域と言語のオプション」で設定した形式（"yyyy/MM/dd"など）になる。
さて本題だが、Weekday関数は引数に指定した曜日を示す数値を返し、その値をWeekdayName関数の引数とすることで曜日名が得られる。これらの関数には、1週間の最初の日を何曜日にするかを指定する引数や、その引数に指定する曜日を意味する定数が用意されているので、余裕があればヘルプを見てもらいたい。
日付処理関数 その3（日時を計算する）
次に日時の計算をする例を見ていこう。
Option Explicit
Dim dtmMyBirthday, lngAge, dtmAge80
dtmMyBirthday = DateValue("昭和53年5月26日") '和暦を示す文字列を日付型に変換
lngAge = DateDiff("yyyy", dtmMyBirthday, Date) 'DateDiff関数で年齢を計算
dtmAge80 = DateAdd("yyyy" ,80 ,dtmMyBirthday)'DateAdd関数で80歳になる日付を計算
MsgBox "私の誕生日は" & dtmMyBirthday & "で、" & vbCrLf & _
"年齢は" & lngAge & "歳です。" & vbCrLf & _
"80歳になるのは" & dtmAge80 & "です。"
実行結果は次のとおり。
DateDiff関数、DateAdd関数の実行例まず計算の前に、和暦を扱う方法を述べる。先ほど説明した日付リテラルには和暦を指定することはできないが、和暦を示す文字列をDateValue関数で日付型に変換することができる。"S53-5-26"などの省略した形式も認識する。もちろんDateValue関数は"1978/5/26"などの西暦も指定できる。
さて、DateDiff関数は、2つの日付・時刻の間隔を求める関数で、これらはそれぞれ第2引数と第3引数に指定する。第1引数には、次の表のように、日付や時間などの間隔を示す文字列を指定する。
| 設定値 | 内容 |
|---|---|
| yyyy | 年 |
| q | 四半期 |
| m | 月 |
| y | 年間通算日 |
| d | 日 |
| w | 週日 |
| ww | 週 |
| h | 時 |
| n | 分 |
| s | 秒 |
| DateDiff関数などの第1引数に指定する文字列の意味 | |
ここでは年齢を求めたいので、年を意味する"yyyy"を指定している。するとdtmMyBirthdayとDate（今日）の間隔が年の単位で返され、結果として年齢が求められるというわけである。
ある日時に時間を加算あるいは減算するときに用いるのがDateAdd関数だ。第1引数にはDateDiff関数と同じく追加する時間間隔の単位を指定し、第2引数に加える値を指定、第3引数に基準となる元の日時を記述する。ここでは、dtmMyBirthdayの80年後の年月日を求めている。減算するとき、すなわちある日時からさかのぼった日時を計算するには、第2引数に負の数（−1など）を指定するとよい。なお、lngAge変数の接頭辞は長整数型 （Long）を意味している。
最後に1つ、日付処理関数を用いた例題を出そう。日付が例えば#2006/8/7#なら、その日付から"20060807"という8けた数字の文字列を返して表示するコードを考えてもらいたい。また、その逆、例えば"20151021"という8けた数字の文字列から#2015/10/21#という日付型の値を返すのにも挑戦しよう。どちらも、文字列処理関数を併用する。
マーカーで隠れたところを選択してチェックしてみよう。
Option Explicit
Dim dtmDate,strDate
'日付型のデータから数字の文字列を得る
dtmDate = #2006/8/7#
strDate = Year(dtmDate) & Right("0" & Month(dtmDate), 2) & Right("0" & Day(dtmDate), 2)
MsgBox dtmDate & "→" & strDate
'数字の文字列から日付型のデータを得る
strDate = "20151021"
dtmDate = DateSerial(Left(strDate, 4), Mid(strDate, 5, 2), Right(strDate, 2))
MsgBox strDate & "→" & dtmDate
スクリプトの実行結果は次のようになる。
日付と数字の文字列の相互変換少し難しかったかもしれないが、お分かりになっただろうか？
日付型のデータから数字の文字列を得る方では、8けたの文字列を取得するために、Month、Day関数の戻り値の左に"0"という文字列を足し、Right関数を使い、右から2文字を取ることで実現している。こうすることで、月、日がそれぞれ10未満の場合、10以上の場合どちらにも対応できる。
数字の文字列から日付型のデータを得る方では、最初にLeft、Mid、Right関数を用いて文字列を年月日に切り分け、それをDateSerial関数に渡すことで実現している。DateSerial関数は引数として数値型を取るが、"2015"のような文字列はそのまま2015という数値に変換され、解釈される。このようなデータ型の変換は暗黙に行われるが、次回、明示的な変換も含めて、データ型について詳細に解説する予定である。
今回は、文字列、数値、日付を扱う関数を取り上げ、それらを単独、あるいは組み合わせることで、さまざまな用途に利用可能なことを示した。次回は、今回説明を省略したデータ型についての説明と、データ型を処理する関数群を取り上げる。また、VBScriptを理解するうえで欠かせない知識となる「配列」とそれらを扱うステートメントを取り上げる。
Copyright© Digital Advantage Corp. All Rights Reserved.
注目のテーマ
ITmediaはアイティメディア株式会社の登録商標です。