第6回 VBScriptの配列を極める：基礎解説 演習方式で身につけるチェック式WSH超入門（3/5 ページ）

[牟田口大介（Microsoft MVP Visual Developer - Scripting），著]

　固定サイズ配列は宣言するとサイズを変更できないのに対し、スクリプト中でサイズを自由に変更できる配列を「動的配列」という。概念図を示すと次のようになる。

動的配列の概念図
動的配列は、箱の数を自由に変えられる配列である。

　このように動的配列は、固定サイズ配列ではできなかった、箱の数の変更が可能な配列である。

　VBScriptで動的配列を宣言するには次のようにする。

Option Explicit
Dim a()

　Dimステートメントで変数名の後に()を書く。このとき()内に数値を指定しないのがポイントである。

　宣言した動的配列のサイズを変更するときにはReDimステートメントを用いる。

次の例をご覧いただきたい。

Option Explicit
Dim intNumbers() '動的配列を宣言
ReDim intNumbers(3) '動的配列のサイズを4に

Dim intCounter 'ループカウンタ変数
For intCounter = 0 To 3
    '配列の0〜3までに値を代入
    intNumbers(intCounter) = intCounter * 2
Next

'動的配列のサイズを1増やす（値は保持）
ReDim Preserve intNumbers(4)
intNumbers(4) = 8

Dim intTemp, strMessage
strMessage = ""
For Each intTemp In intNumbers '全要素に対して繰り返す
    ',で文字列をつなげる
    strMessage = strMessage & intTemp & ","
Next
MsgBox strMessage

　この例では、最初に動的配列を宣言し、次の行で配列のサイズを変更している。ここでは大きさを4（添え字は“(3)”）にし、これらの要素に先ほどと同様に値を代入している。その後、ReDimステートメントにPreserveキーワードを付けて動的配列のサイズを1つ大きくしている。Preserveキーワードを付けると、配列の各要素の既存の値が保持されたままサイズが変更される（付けない場合は配列の全要素が破棄される）。また、動的配列のサイズを小さくすると、小さくなった分、配列の一部の要素が破棄される。

　なお、このスクリプトにおいて、Dim intNumbers()の行は省略可能である。つまり、いきなりReDimでサイズを指定した動的配列を作成可能だ。DimとReDimの違いは、固定サイズか動的かと、Dimでは数値リテラルしか指定できないのに対し、ReDimは変数や式も指定可能という点である。

　この例では、動的配列の利便性が分かりにくいかもしれないので、次に動的配列を活用した例題を取り上げよう。文字列をInputBox関数のダイアログに入力すると、その文字を逆から読んだ場合の文字列を表示するスクリプトを考える（実はその操作を行うためにVBScriptにはStrReverse関数が用意されているのだが、今回は例題としてあえて同様の動作をするスクリプトを取り上げる）。

マーカーで隠れたところを選択してチェックしてみよう。

---

Option Explicit

Dim strString, intLength
strString = InputBox("好きな言葉を入力してください")
intLength = Len(strString) - 1 '配列のサイズ

Dim strChrs() '動的配列を宣言
ReDim strChrs(intLength) ReDim strChrs(intLength) '動的配列のサイズを変更

Dim intCounter
For intCounter = 0 To intLength
'ループカウンタを配列のサイズ分回す
    '1文字ずつ配列に代入
    strChrs(intCounter) = Mid(strString, intCounter + 1, 1)
Next

Dim strReverseString
strReverseString = ""
For intCounter = intLength To 0 Step -1
'ループを逆順に回す
    strReverseString = _
    strReverseString & strChrs(intCounter) '文字列を結合
Next

MsgBox "「" & strString & "」を逆から読むと" & "「" & strReverseString & "」"

　例えばこのスクリプトで表示されるダイアログに、「とくれせんたぼーび」と入力すると、結果は次のように表示される。

動的配列の使用例
動的配列を使って、入力した文字列を逆から読むとどうなるかを表示している。

　このスクリプトでは、ReDimステートメントを用い、配列のサイズを入力した文字列のサイズに動的に変更しているのがポイントである。このように、配列のサイズがあらかじめ分からない場合、動的配列ではスクリプト中の変数で指定することが可能である。